Pular para o conteúdo principal

Postagem em destaque

Postado por

BlackTDN :: LeetCode (17) :: Comparando Implementações do Desafio "Letter Combinations of a Phone Number" em Harbour e TOTVS TLPP

_Créditos das imagens: ChatGPT_ # LeetCode (17) :: Comparando Implementações do Desafio "Letter Combinations of a Phone Number" em Harbour e TOTVS TLPP O desafio [**"Letter Combinations of a Phone Number"**](https://leetcode.com/problems/letter-combinations-of-a-phone-number/description/) (Combinações de Letras de um Número de Telefone) é um problema clássico de programação que envolve a geração de todas as combinações possíveis de letras que um número de telefone pode representar, com base no mapeamento tradicional dos teclados de telefone. Abaixo, comparamos duas implementações desse desafio: uma em **Harbour** e outra em **TOTVS TLPP** (TOTVS Language Plus Plus). ## O Desafio Dada uma string contendo dígitos de 2 a 9, retorne todas as combinações possíveis de letras que esses dígitos podem representar. O mapeamento dos dígitos para as letras é o mesmo dos teclados de telefone tradicionais: - 2: "abc" - 3: "def" - 4: "ghi" - 5: ...
Postar um comentário
Leia mais
Marcadores
Postado por

BlackTDN :: ADVPL ~ dbChangeAlias 

#include "tbiconn.ch"
#include "protheus.ch"
/*
    Programa    : U_CT1CTASup.prw
    Funcao      : U_CT1CTASup
    Autor       : Marinaldo de Jesus [http://www.blacktdn.com.br]
    Data        : 11/07/2012
    Uso         : Obter o valores para os campos CT1_CTASUP e CT1_DC
*/
User Function CT1CTASup( lRPC , cEmp , cFil , cModulo ) 

    DEFAULT lRPC    := MyIsBlind()

    IF ( lRPC )

        DEFAULT cEmp    := "99"
        DEFAULT cFil    := "01"
        DEFAULT cModulo := "CTB"

        RPCSetType(3)
        #IFDEF TOP
            SetTopType("A")
        #ENDIF    
        PREPARE ENVIRONMENT EMPRESA ( cEmp ) FILIAL ( cFil ) MODULO ( cModulo )
            SetsDefault()
            SetModulo("SIGACTB","CTB") 
    EndIF

    Processa( { || CT1CTASup() } , "Atualizando Conta Superior e Digito" , "Aguarde" )

    IF ( lRPC )
        RESET ENVIRONMENT
    EndIF

    ApMsgAlert( "Atualização Conta Superior e Digito Finalizada" )

Return(    NIL )

/*
    Programa    : U_CT1CTASup.prw
    Funcao      : CT1CTASup
    Autor       : Marinaldo de Jesus [http://www.blacktdn.com.br]
    Data        : 11/07/2012
    Uso         : Obter o valores para os campos CT1_CTASUP e CT1_DC
*/
Static Procedure CT1CTASup() 

    Local cCTA
    Local cDgC
    Local cSup

    Local cCT1Alias    := GetNextAlias()

    ChkFile("CT1")

    dbChangeAlias("CT1",cCT1Alias)

    ChkFile("CT1")

    (cCT1Alias)->( dbGoTop() )

    ProcRegua(0)

    While (cCT1Alias)->( !Eof() )
        IncProc()
        cCTA    := (cCT1Alias)->CT1_CONTA
        cSup    := CTBCTASup(cCTA)
        IF (cCT1Alias)->( RecLock( cCT1Alias , .F. ) )
            (cCT1Alias)->CT1_CTASUP    := cSup
            (cCT1Alias)->( MsUnLock() )
        EndIF
        cDgC    := CTBDigCont(cCTA)
        IF (cCT1Alias)->( RecLock( cCT1Alias , .F. ) )
            (cCT1Alias)->CT1_DC        := cDgC
            (cCT1Alias)->( MsUnLock() )
        EndIF
        (cCT1Alias)->( dbSkip() )
    End While

    (cCT1Alias)->( dbCloseArea() )
    CT1->( dbCloseArea() )

Return

/*
    Programa    : U_CT1CTASup.prw
    Funcao      : MyIsBlind
    Autor       : Marinaldo de Jesus [http://www.blacktdn.com.br]
    Data        : 11/07/2012
    Uso         : Verificar Blind
*/
Static Function MyIsBlind()
    Local oWnd    := GetWndDefault()
Return( IsBlind() .and. ( oWnd == NIL ) .and. ( Select("SM0") == 0 ) )

Enviar esta postagem
Marcadores:

Comentários

  1. Anônimo18 de julho de 2012 às 15:54

    Naldo,
    dbChangeAlias() funcionaria como a CHKFILE()?

    Ver: http://tdn.totvs.com/pages/viewpage.action?pageId=6814713

    abs,

    ResponderExcluir
    Respostas
    1. иαldσ dj19 de julho de 2012 às 10:19

      Não! dbChangeAlias(cAlias,cNewAlias), função da API, altera o "apelido" da tabela enquanto que ChkFile() (Obtenha os parâmetros formais com GetFuncPrm("ChkFile")), função em ADVPL, abre uma tabela e atribui-lhe um apelido usando dbUseArea(). Um uso para dbChangeAlias(), como no exemplo, é ter a mesma tabela em memória, com Aliases diferentes de forma a não ser necessário salvar e restaurar o "ponteiro" da tabela no caso de se executar uma função do RPO que o desposicione. No exemplo alteramos o Apelido(Alias) da tabela CT1 para um apelido válido retornado pela GetNextAlias() e abrimos uma "nova instância" da mesma tabela usando ChkFile() (poderia ser dbUseArea()) ou simplesmente referenciando o alias CT1 (que seria aberta pela rotina de tratamento de erro uma vez que o Alias CT1, após dbChangeAlias(), não existir mais). No exemplo, A Função CTBCTASup necessita usar o Alias CT1 para encontrar a Conta Superior e, para evitar salvar e restaurar o "ponteiro do registro e índice da CT1) atribuimo-lhe um novo Apelido. Neste caso teremos 2x a mesma tabela em memória mas com Aliases diferentes (podendo navegar de forma independente entre os seus registros).

      Excluir
  2. Kelven G. Campos10 de abril de 2013 às 16:27

    Naldo,

    será que é possível manipular a mesma tabela com alias diferente com o objeto FWmBrowse()?? (setAlias)
    (

    estou utilizando a FWmBrowse() e estou tendo problemas.
    abro uma tabela com a FWmBrowse e em seguida a mesma tabela é aberta com FWmBrowse so q com filtros diferentes.
    ae quando tento manilupar os dados da conflito entre os dois FWmBrowse.

    grato pela ajuda!

    ResponderExcluir

Postar um comentário

Postagens mais visitadas